在進入閱讀本文章的內容之前，思考一下如果想要製作選取方塊的效果，

要怎麼製作呢?

或許您已經製作過核取方塊，並用在很多地方。

但如果當您的Excel內需要重複設定大量的核取方塊，

想使用VBA，但不知道怎麼處理時，可以參考本篇文章。

或許可以給您一點想法也說不定。

如果你在您的程式中也遇到相同的問題，不妨以以下簡單的方式，

測試看看。

Sub AddCheckBoxes()

  '宣告變數和資料型態
  Dim count As Integer 'count為儲存格計算用宣告為整數
  
  '宣告CheckBox新增時所在位置的變數
  Dim cbLeft As Double 'CheckBox左側位置
  Dim cbTop As Double  'CheckBox上端位置
  Dim cbWidth As Double  'CheckBox的寬度
  Dim cbHeight As Double 'CheckBox的高度
  
  '關閉畫面更新
  Application.ScreenUpdating = False
  
  'For迴圈列出需要的核取方塊
  '範例中最後一行數字為11
  For count = 2 To 11
  
      '設定B列 核取方塊(表單控制項) ============================
      With Range("B" & count)
          cbLeft = .Left
          cbTop = .Top
          cbWidth = .Width
          cbHeight = .Height
      End With
      
  '新增核取方塊(表單控制項)及核取方塊的屬性選項
  ActiveSheet.CheckBoxes.Add(cbLeft, cbTop, cbWidth, cbHeight).Select
  With Selection
      .Caption = ""       '核取方塊文字為空白
      .Value = xlOff      '為非核取狀態
      .Display3DShading = False   '3D陰影不顯示
      .LinkedCell = Range("C" & count).Address   '連結的儲存格
  End With
  
  '設定C列的值為False ==============================
  
  Range("C" & count).Value = False
  
  '設定格式化條件 =================================
  '追加格式化條件
  Range("A" & count).FormatConditions.Add xlExpression, xlEqual, "=$C$" & count
  
  '新增第一個條件式的字型格式
  With Range("A" & count).FormatConditions(1).Font
    .Strikethrough = True    '刪除線
    .Color = RGB(255, 0, 0)    '顏色設定為紅色
    .TintAndShade = 0    '色彩變淡或變深設為中性
  End With
  
  '如果為True則停止-設為False
  Range("A" & count).FormatConditions(1).StopIfTrue = False
 Next
 
 '開啟畫面更新
 Application.ScreenUpdating = True
 
 '回復到選擇A1的狀態
 Range("A1").Select
   
End Sub

關於階段2可參考以下連結影片

開始製作程式: 階段3

Point!

1. 清除核取方塊

2. 全選

3. 取消全選

4. 效果確認

階段3主要撰寫清除核取方塊，還有全部選取，

以及取消全部選取的程式。

階段3裡的清除核取方塊並非必要，只是在於如果新增A欄的資料後，

如果沒有清除之前的核取方塊，又按下新增按鈕時，

核取方塊會另外又多新增一個疊在上面。

多重堆疊的核取方塊有可能會造成錯誤。

因此設計這個功能，防止新增的核取方塊不斷堆疊。

全部選取和取消全部選取可能並非經常使用之功能，

可參考使用。

注意在下方的程式，只設定A2~A11，也就是範例的範圍，

如果需要更大的範圍，請參考以下程式碼再修改設定。

以符合您的需求。

清除核取方塊

程式碼

Sub RemoveCheckboxes()

  '清除A2到A11的條件式格式設定資料
  Range("A2:A11").FormatConditions.Delete
  
  '清除B2到C11的資料
  Range("B2:C11").ClearContents
  
  '宣告cb變數為Checkbox物件類型
  Dim cb As CheckBox
  
  '使用For Each 針對目前工作表內的核取方塊做循環處理
  For Each cb In ActiveSheet.CheckBoxes
      '刪除
      cb.Delete
  Next
  
End Sub

全部選取

程式碼

Sub SelectAll()

    '將C2~C11範圍的值設定為True
    Range("C2:C11").Value = True
    
End Sub

取消全部選取

程式碼

Sub DeselectAll()

    '將C2~C11範圍的值設定為False
    Range("C2:C11").Value = False
    
End Sub

關於階段3可參考以下連結影片

透過VBA 製作新增核取方塊效果

目錄

前言

開始製作程式: 階段1 程式說明

使用手動製作核取方塊

開始製作程式: 階段2

程式碼

開始製作程式: 階段3

清除核取方塊

程式碼

全部選取

程式碼

取消全部選取

程式碼

聯絡表單